@Zitronella wegen Portable Starter

Weil ich das anderweitig gelesen habe, dass man evtl die Portable als würg-around Standardbrowser nutzen kann seit dedizierten Profile:
https://www.winhelponline.com/blog/register-…grams-in-vista/

Ich weiss, dass der Starter von Caschy automatisch -no-remote hinzufügt, sobald eine laufende Instanz erkannt wird. Ist das bei dir auch noch so? Dann dürfte der Starter von Caschy und dir in Verbindung mit dem verlinkten Tool nicht zielführend sein.

War das jetzt zu schnell in Gedanken?

Also mit nur einem Firefox und einem Standardprofil ist es egal, damit dürften die meisten dieses neue Feature gar nicht bemerken. Die Portable hingegen wird ja mit Parameter für das Profil gestartet und Firefox.exe war bislang ja auch darüber ansprechbar (ohne -no-remote) und hat praktisch diese Anfragen abgefangen. Dass ist ja seit dedizierten Profilen nicht mehr so. Jetzt sind die halt darauf gekommen, den Starter als Standardbrowser einzutragen - macht ja Sinn - und damit wird ja dann praktisch das Profil wieder mit übergeben, was ja den grundsätzlichen Überlegungen entspricht. Was aber eben nicht bedacht wurde, dass der Starter ein -no-remote hinzufügt, sobald eine laufende Instanz erkannt wird. Damit ist das Tool von oben praktisch wertlos, weil der Starter nicht mitspielt.

Laut gedacht:
Der Starter müsste eigentlich jetzt eigentlich zusätzlich feststellen, ob seine Firefox-Instanz schon läuft, ob er schon mal aufgerufen wurde. Und das ist nur möglich, wenn es den Pfad zur laufenden Instanz ausliest, es reicht keine INI oder "Flag" dafür, weil der Starter sich ja danach direkt wieder beendet und Firefox arbeiten lässt.

Abseits davon, folgendes (ähnlich) nutze ich hier, um Firefox festzulegen:
HKEY_CLASSES_ROOT\Applications\firefox.exe\shell\open\command
@="X:\Firefox\firefox.exe" "%1"

Wenn man nicht zwingend die profiles.ini nutzt, sondern -profile <pfad-zum-profil> könnte man damit verschiedene Firefox auf sich festlegen, wenn man die EXE umbenennt.

HKEY_CLASSES_ROOT\Applications\firefox.exe\shell\open\command
@="X:\Firefox\firefox.exe" "%1"

HKEY_CLASSES_ROOT\Applications\firefox68.exe\shell\open\command
@="X:\Firefox68\firefox68.exe" -profile <pfad68> "%1"

HKEY_CLASSES_ROOT\Applications\firefox69.exe\shell\open\command
@="X:\Firefox69\firefox69.exe" -no-remote -profile <pfad69> "%1"

In diesem Zweig stehen u.a. notepad.exe, winrar.exe und andere, die man so ohne genaue Pfadangabe unter Start > "Ausführen" aufrufen kann.

Beides liesse sich sogar verbinden, weil der Starter Parameter (zB Webseite) durchreicht

HKEY_CLASSES_ROOT\Applications\firefox.exe\shell\open\command
@="X:\Firefox Portable\firefoxstarter.exe" "%1"

Nochmal auf das Tool "RegisterFirefoxPortable.exe" zu kommen - ich weiss nicht, was es tut, ich nutze kein NET Framework 3.5, welches benötigt wird. Kann ich nur unter Windows 7 testen.

Das hatte ich vor dem Schreiben ja noch gelesen und genau darauf beziehe ich mich ja. Bis v66 "firefox.exe" (egal welcher, ohne -no-remote) Aufrufe noch mit aufgefangen. Mit -no-remote hat es sich ja eh erledigt. Das Problem ergibt sich ja erst mit v67, dass Firefox selbst bei einer gestarteten Portable ein Profil im Benutzerordner erstellt bzw anfragt (Profilmanager). Und das muss der Portable Starter abfangen, nicht mehr Firefox.

Die Portable als einmaliger Aufruf funktioniert, eine weitere Portable ja auch (-no-remote wird hinzugefügt), nur eben nicht mehr die Übergabe an eine laufende firefox.exe, weil die wegen der dedizierten Profile anders arbeitet.

Das obige mit der Registry passt so nicht, es müsste sein
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\firefox.exe
@="X:\\Firefox\\Firefox.exe"
"Path"="X:\\Firefox"

wird dann zu
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\firefox.exe
@="X:\\Firefox\\FirefoxLoader.exe"
"Path"="X:\\Firefox"

(für die Portable, siehe Erklärung oben)
Und der Code für den Starter muss erweitert werden, damit er bei Erkennung seine eigenen Instanz (siehe dein pastebin, BENE) eben auf Firefox mit gleichem Parameter für den Pfad starten.

Um bei einem bildhaftem Beispiel zu bleiben, weil es bei vielen auch so passt:

iCafee - Firefox Portable & Thunderbird Portable. TB (jedes andere beliebige Programm) kennt nur "firefox.exe" und weiss nicht, wo es liegt.
Bislang reichte der Aufruf firefox.exe <link_aus_email>, jetzt muss bei einem Firefox Portable explizit das Profil angegeben werden, ansonsten landet der Aufruf als Profil im Benutzerordner. Problem dabei ist, dass weder der Ort von Firefox Portable (mitsamt Starter) bekannt ist noch der Ordner.

Hilfreich wäre dann der Ort aus der Registry, den man setzen könnte (unter Berücksichtigung vorhandener Einträge), oder den anderen Program mitteil, wo der Portable Starter liegt.

---

Nachtrag - der Code des Portable Starters erkennt schon seine eigene Instanz. Übersehen und zu kompliziert gedacht. Also müsste man nur den externen Aufruf an den Starter weiterreichen, nicht mehr an Firefox (siehe oben).

Ich sehe grad noch einen Unterschied zum Code von Bene.

Dim $COMMANDLINE, $running, $noremote
If $CMDLINE[0] Then $COMMANDLINE = $CMDLINE[1]


$noremote = ""


If ProcessExists("firefox.exe") Then
	$running = _ProcessGetLocation("firefox.exe")
	If $running <> (@ScriptDir & "\Firefox\firefox.exe") Then
		$noremote = "-no-remote "
	EndIf
EndIf


Run("Firefox\firefox.exe " & $noremote & "-profile Profilordner " & $COMMANDLINE)

D.h. der Code von Bene kann das gar nicht umsetzen, der macht nur einen neuen Tab auf wenn überhaupt.

Was mir grad noch einfällt, der Starter stammt aus Zeiten, von noch kein multiprocess gab. Man müsste noch austesten, ob mit psapi nur die erste gefundene Instanz übergeben wird oder mehr als eine, ersteres wäre irgendwie schlecht.

https://www.autoitscript.com/forum/topic/88…om-any-process/
:idea:

Eben etwas recherchiert und das ist bei rausgekommen:

#include <winapiex.au3>   ; _GetPrivilege_SEDEBUG() uses this include. My function needs none.
#include <array.au3>    ; Needed to display array in example. Not needed by Func.

Dim $COMMANDLINE, $flag, $profilfolder, $profilfolderfull, $jsonoption, $guid, $guidlast

If $CMDLINE[0] Then $COMMANDLINE = $CMDLINE[1]

If Not (FileExists (@ScriptDir & "\Firefox\firefox.exe")) Then
    MsgBox (16, "Fehler", "Firefox wurde nicht gefunden:" & @CRLF & @CRLF & @ScriptDir & "\Firefox\firefox.exe", 3)
    Exit
EndIf

read_ini()
json()
findprocess()

$noremote = ""
if $flag then $noremote = "-no-remote "
Run(@ScriptDir & "\Firefox\firefox.exe " & $noremote & "-profile " & $profilfolder & " " & $COMMANDLINE)
Exit(0)

;functions

Func read_ini()
  ;read ini
  $profilfolder     = IniRead (@ScriptDir & "\portable.ini", "system", "folder", "Profilordner")
  $profilfolderfull = @ScriptDir & "\" & $profilfolder
  $jsonoption       = IniRead (@ScriptDir & "\portable.ini", "system", "action", "delete")
EndFunc

Func json()
  If $jsonoption == "" Then
    $jsonoption = "delete"
  ElseIf (Not($jsonoption == "delete") And Not($jsonoption == "save")) Then
      $jsonoption = "delete"
      $guid = ""
      IniWrite (@ScriptDir & "\portable.ini", "system", "action", $jsonoption)
  EndIf
  
  If $jsonoption == "save" Then
    $guidlast = IniRead (@ScriptDir & "\portable.ini", "system", "last", "")
    $guid = RegRead ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Cryptography", "MachineGuid")
    $guid = StringReplace ($guid, "-", "")
  
    ;save last state
    If Not ($guidlast == "") Then
      If FileExists ($profilfolder & "\addonStartup.json.lz4") Then
        FileMove ($profilfolder & "\addonStartup.json.lz4", @ScriptDir & "\_guid\" & $guidlast & "\", $FC_OVERWRITE + $FC_CREATEPATH)
      EndIf
    EndIf
    IniWrite (@ScriptDir & "\portable.ini", "system", "last", $guid)
  EndIf
  
  If $jsonoption == "save" Then
    ;recover saved state
    If FileExists (@ScriptDir & "\_guid\" & $guid & "\addonStartup.json.lz4") Then
      FileCopy (@ScriptDir & "\_guid\" & $guid & "\addonStartup.json.lz4", $profilfolder & "\", $FC_OVERWRITE )
    EndIf
  EndIf
EndFunc

Func findprocess()
$list=ProcessList("firefox.exe")
  Redim $list[ubound($list,1)][3]
  
  $flag = False
  for $i=1 to ubound($list,1)-1
      $list[$i][2]=_WinAPI_GetProcessFileName($list[$i][1])
      If Not(StringInStr ($list[$i][2], @ScriptDir & "\Firefox\firefox.exe")) Then
        $flag = True
        ExitLoop
      EndIf
  Next
EndFunc</array.au3></winapiex.au3>

- Parameter berücksichtigt
- Firefox-Prozesse eingelesen
- Pfad vergleichen
- und ggf mit no-remote starten

Update:

- save/recover "addonStartup.json.lz4" für jedes Gastsystem

Update2:

- Struktur geändert

- Option für Löschen(Standard)/Speichern der Datei (analog zu John T Haller bei portableapps.com)

Hier wird multiprocess berücksichtigt, was bei psapi vorher nicht der Fall war.

Jetzt fehlt nur noch die Festlegung auf den Starter als Ausgangspunkt für externe Aufrufe.

#Code-Korrektur

Funktioniert auf x86 und x64 (getestet unter Windows 8 und 10)
Kann sich jeder mit AutoIt selbst zur EXE kompilieren
https://www.autoitscript.com/site/

Update:

- save/recover "addonStartup.json.lz4" für jedes Gastsystem

Wegen

Portable-Version FF - Aktivierte Add-ons werden nicht in Adress-Leiste angezeigt - nach PC-Wechsel

In dieser Daten werden die pfade zu den Extensions gespeichert und das kann je nach Gastsystem abweichen und daher der beschriebene Effekt. Der Starter prüft und stellt ggf eine passende Ausgabe wieder her.

Ganz Wichtig: Firefox Portable muss in solchen Fällen zwei Mal gestartet werden!

Es gäbe noch die Möglichkeit, das LZ4 zu entpacken, müsste dann aber auch neu gepackt werden. Problematik dabei ist, dass Mozillas LZ4-Format abweicht vom Standard und auch eigene Konventionen verfolgt, die a) in zwei extra Tools ended und b) danach weiter modifiziert werden müssen. Derzeit sind meine eigene Fähigkeiten dahingehend begrenzt und deswegen nicht umsetzbar.

Quelle: https://github.com/avih/dejsonlz4

Update2:

- Struktur geändert

- Option für Löschen(Standard)/Speichern der Datei (analog zu John T Haller bei portableapps.com)

Update

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=..\icons\firefox57.ico
#AutoIt3Wrapper_outfile=..\FirefoxLoader.exe
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#region
#endregion

#include <WinAPIEx.au3>
#include <array.au3>

Global Const $firefox_exe    = "Firefox.exe"
Global Const $profilfolder   = "Profilordner"
Global Const $jsonfile       = "addonStartup.json.lz4"
Global Const $compfile       = "compatibility.ini"

Dim $COMMANDLINE, $runflag
Dim $firefoxfull, $profilfolderfull
Dim $compfilefull, $jsonfilefull
Dim $wow64, $bits, $bits_folder

;read command line
If $CMDLINE[0] Then $COMMANDLINE = $CMDLINE[1]

check_firefox()
files()
findprocess()

$noremote = ""
If $runflag then $noremote = "-no-remote "
Run($firefoxfull & " " & $noremote & "-profile " & $profilfolder & " " & $COMMANDLINE)
Exit(0)


;check bits x86/x64 and firefox
Func check_firefox()
  $wow64 = @AutoItX64
  If $wow64 = 0 Then
    $bits_folder = "Firefox"
    $bits        = "x86"
  ElseIf $wow64 = 1 Then
    $bits_folder = "Firefox64"
    $bits        = "x64"
  Else
    MsgBox(16, "Fehler", "Dieses System wird nicht unterstützt. Abbruch!", 3)
    Exit
  EndIf

  $profilfolderfull = @ScriptDir & "\" & $profilfolder
  $firefoxfull = @ScriptDir & "\" & $bits_folder & "\" & $firefox_exe

  If($bits == "x64") Then
    If Not(FileExists($firefoxfull) Then
      $bits_folder = "Firefox"
      $bits       = "x86"
      $firefoxfull = @ScriptDir & "\" & $bits_folder & "\" & $firefox_exe
    EndIf
  EndIf

  If Not(FileExists($firefoxfull)) Then
    MsgBox(16, "Fehler", "Firefox " & $bits & " wurde nicht gefunden:" & @CRLF & @CRLF & $firefoxfull, 3)
    Exit
  EndIf
EndFunc

;addonStartup.json.lz4, compatibility.ini
Func files()
  $jsonfilefull = $profilfolderfull & "\" & $jsonfile

  If FileExists($jsonfilefull) Then
    FileDelete($jsonfilefull)
  EndIf

  $compfilefull = $profilfolderfull & "\" & $compfile

  If FileExists($compfilefull) Then
    FileDelete($compfilefull)
  EndIf
  Sleep(300)

  $sFile = FileOpen($compfilefull, 2)
  FileClose($sFile)
  Sleep(300)

  If FileExists($compfilefull) Then
    FileSetAttrib($compfilefull, "+R")
  EndIf
EndFunc

;find associated firefox with portable starter
Func findprocess()
$list=ProcessList($firefox_exe)
  Redim $list[ubound($list,1)][3]
  
  $runflag = False
  for $i=1 to ubound($list,1)-1
      $list[$i][2]=_WinAPI_GetProcessFileName($list[$i][1])
      If Not(StringInStr($list[$i][2], $firefoxfull)) Then
        $runflag = True
        ExitLoop
      EndIf
  Next
EndFunc

;end

Kompilation mit https://autoit.de/

Nach Fehlersuche und Mitarbeit von 2002Andreas bzgl. "MultipleFirefoxLoader"

Änderungen wie folgt:

- setzen des Arbeitsverzeichnisses, sonst wollen andere Instanzen das gleiche Profil nutzen

- bei einer vorhandenen Sitzung der gleichen Portable passiert nichts weiter

- Code-Vereinfachung

- auf Wunsch Symbole für Final/Beta/Nightly aus den offiziellen Assets

Product Identity Assets

The Photon Design System houses guidelines, reusable UI components, templates, and other resources to help you create products for Firefox users.

design.firefox.com

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_icon=firefox_final64.ico
#AutoIt3Wrapper_outfile=..\FirefoxLoader.exe
#AutoIt3Wrapper_UseUpx=n
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#region
#endregion

#include <WinAPIEx.au3>
#include <array.au3>

Global Const $product      = "Firefox"
Global Const $product_exe  = $product & ".exe"
Global Const $profilfolder = "Profilordner"
Global Const $msgheader    = "Fehler"
Global Const $msgtext1     = "Dieses System wird nicht unterstützt. Abbruch!"
Global Const $msgtext2     = " wurde nicht gefunden:"

Dim $COMMANDLINE, $profilfolderfull, $wow64

;read command line
If $CMDLINE[0] Then $COMMANDLINE = $CMDLINE[1]

$profilfolderfull = @ScriptDir & "\" & $profilfolder
$productfull = check_product()
$noremote = findprocess()

;set working dir / Arbeitsverzeichnis
FileChangeDir (@ScriptDir)

;start product
Run($productfull & " " & $noremote & "-profile " & $profilfolder & " " & $COMMANDLINE)

Exit(0)


;check product path
Func check_product()
  $wow64 = @OSArch
  If $wow64 == "X86" Then
    $pathfull = @ScriptDir & "\" & $product & "\" & $product_exe
  ElseIf $wow64 == "X64" Then
    $pathfull = @ScriptDir & "\" & $product & "64\" & $product_exe
    If Not(FileExists($pathfull)) Then
      $pathfull = @ScriptDir & "\" & $product & "\" & $product_exe
    EndIf
  Else
    MsgBox(16, $msgheader, $msgtext1, 3)
    Exit
  EndIf

  If Not(FileExists($pathfull)) Then
    MsgBox(16, $msgheader, $product & $msgtext2 & @CRLF & @CRLF & $pathfull, 3)
    Exit
  EndIf
  Return($pathfull)
EndFunc

;find associated product with portable starter
Func findprocess()
$list=ProcessList($product_exe)
  Redim $list[ubound($list,1)][3]
  for $i=1 to ubound($list,1)-1
    $list[$i][2]=_WinAPI_GetProcessFileName($list[$i][1])
    If (StringInStr($list[$i][2], $productfull)) Then
      ;same portable running = exit
      Exit
    EndIf
  Next

  for $i=1 to ubound($list,1)-1
    $list[$i][2]=_WinAPI_GetProcessFileName($list[$i][1])
    If Not(StringInStr($list[$i][2], $productfull)) Then
      ;another instance of product running = set -no-remote
      Return ("-no-remote ")
    EndIf
  Next
  Return ("")
EndFunc

;end

Resultat und Quellcode als ZIP (Update am 8.2.2023 abends)

Für Firefox

Firefox_Portable_2023-02-08_3.zip

Shared with Dropbox

www.dropbox.com

Für Thunderbird

Thunderbird_Portable_2023-02-08_1.zip

Shared with Dropbox

www.dropbox.com

Hinweis: alle Dropbox-Nachfragen wegklicken und dann oben Links "Herunterladen"

Der Starter kann Windows 32- und 64-Bit erkennen und auf entsprechende Builds umschalten. Gibt es beides nicht: Fehlermeldung. Im ZIP ist eine entsprechende funktionierende Ordnerstruktur vorgegeben, ohne Profil und Anwendung, das müsst ihr selbst reinkopieren.

Der Code lässt sich mit Autoit kompilieren, enthält aber dann kein Symbol, dazu braucht es "AutoIt3Wrapper" aus "Scite".

Wer ein anderes Symbol möchte, sollte sich das Script neu kompilieren, ansonsten kann es zu Fehlfunktionen kommen!

Tip: Eine Bearbeitung des Symbols ist hier (getestet) auch mit RessourceHacker machbar.

Scite ist extra:

AutoIt Script Editor Downloads - AutoIt

Overview This is the main download page for the AutoIt Script Editor and related files. Current Versions File Date updated Notes SciTE4AutoIt3.exe (5439Kb)…

www.autoitscript.com

Autoit deutsch hier

Unerledigte Themen - AutoIt.de - Das deutschsprachige Forum.

Und nochmal:

Zitat

Hinweis: alle Dropbox-Nachfragen wegklicken und dann oben Links "Herunterladen"

Update am 7.2.2023 für einen weiteren Starter auf Wunsch. Durch ein neueres Autoit sind auch diverse Falschmeldungen bei Antivirusprogrammen obsolet, allenfalls Kaspersky, McAfee und ein paar unbekannte. Defender ist nicht dabei.

VirusTotal

Hast du die "Automatische Übermittlung von Beispielen" aktiviert?

Ich kann mich nur an meinen Systemen und VT orientieren und da kommt nichts.

Ansonsten steht es jedem frei, sich autoit zu besorgen und selbst zu kopilieren.

Ich habe ein Update auf einer anderen Basis eingestellt in die #7.

Der Aufwand war entsprechend höher, weil die Programmiersprache wesentlich einfacher gehalten ist. Dadurch sind auch die Header kleiner usw.

Zu einer Datei daraus.

VirusTotal